Sumário

# Função ESTILO

Aplica um estilo à célula que contém a fórmula. Após um período de tempo determinado, outro estilo pode ser aplicado.

Esta função sempre retorna o valor numérico 0, o que permite utilizá-la adicionando a função ESTILO a outras funções na mesma célula sem alterar seu valor.

A função STYLE não deve ser usada sem motivo convincente, seu objetivo é o uso com funções Add-In assíncronas para notificar visualmente sobre a disponibilidade de um resultado. Em quase todos os outros casos, usar a formatação condicional é uma escolha melhor.

### Sintaxe

ESTILO("Estilo" [; Tempo [; "Estilo2"]])

Estilo é o nome do estilo de célula a ser aplicado à célula. Os nomes de estilo não diferenciam maiúsculas de minúsculas e devem ser inseridos entre aspas.

Tempo é um intervalo de tempo opcional em segundos. Após decorrido esse tempo, aplica-se o estilo definido em Estilo2. Deixe este parâmetro em branco se não quiser que o estilo seja alterado.

Estilo2 é o nome opcional de um estilo de célula atribuído à célula após o tempo decorrido especificado no parâmetro Tempo. Se omitido, aplica-se o estilo de célula "Padrão".

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

### Exemplos

=10+ESTILO("Bom",60,"Neutro")

Insere o valor 10 na célula e aplica o estilo denominado "Bom". Após 60 segundos, aplica-se o estilo "Neutro".

=A1*A2+ESTILO(SE(ATUAL()<100,"Ruim","Bom"))

Insere o resultado da multiplicação dos valores nas células A1 e A2 e aplica o estilo "Ruim" se o resultado for menor que 100, caso contrário, aplica-se o estilo "Bom". Aqui a função ATUAL() é usada para obter o valor atual da função na célula.

="Total"&T(ESTILO("Resultado"))

Insere o texto "Total" na célula e aplica o estilo denominado "Resultado". Observe que este exemplo lida com valores textuais, portanto, a saída da função ESTILO precisa ser anexada ao texto usando o operador &. A função T() é usada para evitar que o número "0" seja acrescentado ao texto resultante.

#### Informação técnica

Esta função não faz parte do padrão Open Document Format for Office Applications (OpenDocument) Versão 1.3. Parte 4: Formato de Fórmula Recalculada (OpenFormula). O espaço de nomes é

ORG.OPENOFFICE.STYLE

Tópicos relacionados

Página wiki da função ESTILO.

Funções de planilha

Atribuir formatos por fórmula

Função ATUAL

Função T

♥ Doe para nosso projeto! ♥